01 Mar Implication Constraint

SystemVerilog에서 constraint를 작성할 때 조건을 명시하기 위하여 보통 if–else 구문을 많이 사용하게 되는데, 이 외에도 조건을 명시할 수 있는 또 다른 syntax로 implication constraint에 대하여 소개한다. Implication constraint는 -> operator를 사용하며 LRM 상에서는 아래와 같이 정의하고 있다. 예를 들어 a -> b와 같이 constraint를 작성했다고 생각해보자. 이는 a가 true인 경우, b는 반드시 true임을 나타낸다. a가 false인 경우, b는 true일 수도 있고, false일 수도 있다. 즉, Boolean으로 표현하자면 (!a || b)와 동일하다고 이해할 수 있다.

constraint_expression ::==
  ...
  | expression -> constraint_set

Implication constraint를 사용한 아래 code를 살펴보자. 먼저 mode 변수는 random, little, big의 값을 가질 수 있고, len 변수는 1에서 1000 사이의 값을 가질 수 있다. 단, implication constraint를 이용하여 mode가 little인 경우 10보다 작은 값으로 제한되고, mode가 big인 경우 100보다 큰 값으로 제한되도록 설정하고 있다. 참고로 solve–before constraint는 mode의 값이 random, little, big을 골고루 갖도록 하기 위하여 추가하였으며, 자세한 내용은 solve…before Constraint 페이지를 참고하자.

typedef enum bit [1:0] { random = 0, little = 1, big = 2 } mode_e;

class my_class;

  rand mode_e mode;
  rand int unsigned len;

  constraint c {
    solve mode before len;
    len inside { [1:1000] };
    
    /* if-else constraint */
    //if (mode == little) len < 10;
    //else if (mode == big) len > 100;
    
    /* implication constraint */
    mode == little -> len < 10;
    mode == big -> len > 100;
  }
  
endclass: my_class

아래와 같이 randomization과 변수 출력을 여러 차례 반복하도록 code를 작성하여 결과를 확인해보자.

module top;

  my_class c;
  
  initial begin
    c = new();
      
    repeat (10) begin
      void'(c.randomize());
      $display("len = %3d / mode = %s", c.len, c.mode.name());
    end
  end

endmodule: top

mode가 random인 경우, len이 4, 71, 315, 246과 같이 1부터 1000 사이의 모두 가질 수 있다. 또한 mode가 litte인 경우, 8, 4와 같이 10보다 작은 값, mode가 big인 경우 374, 408, 250, 289와 같이 100보다 큰 값을 갖는 것을 확인할 수 있다.

len = 374 / mode = big
len =   4 / mode = random
len =  71 / mode = random
len = 408 / mode = big
len = 250 / mode = big
len = 289 / mode = big
len = 315 / mode = random
len =   8 / mode = little
len = 246 / mode = random
len =   4 / mode = little

References

• https://ieeexplore.ieee.org/document/8299595

IKS

Jung Ik Moon
Verification Engineer

iksciting.com